Структурированные ссылки

Продукт: МойОфис Стандартный 3, МойОфис Профессиональный 3

Приложение: Таблица macOS

Работа со структурированными ссылками поддерживается только в «умных» таблицах.

Использование структурированных ссылок

Формулы со структурированными ссылками оперируют не адресами ячеек и диапазонов ячеек, а именами таблицы и столбцов таблицы, а также названиями областей таблицы.

Ниже приведены примеры обычных и структурированных ссылок.

Описание	Обычная ссылка	Структурированная ссылка
Ссылка на диапазон ячеек столбца Продажи таблицы Таблица1	=МАКС(B2:B8)	=МАКС(Таблица1[Продажи])
Ссылка на область данных таблицы Таблица2	=МАКС(A2:C8)	=МАКС(Таблица2[#Данные])

references

Структурированные ссылки могут использоваться как в таблице, так и за ее пределами.

Если формула со структурированной ссылкой расположена непосредственно в таблице, то указывать название таблицы в данной ссылке не нужно. Если имя таблицы по какой-либо причине указывается в ссылке, то оно автоматически удаляется при вводе формулы. Например, формула =МАКС(Таблица1[Продажи]) будет автоматически исправлена на =МАКС([Продажи]).

Если формула со структурированной ссылкой расположена за пределами таблицы, то указание имени таблицы является обязательным условием.

Синтаксис структурированных ссылок

Структурированные ссылки могут обращаться к следующим данным таблицы:

Указатель	Описание
#Все	Вся таблица, включая строку заголовка и строку итогов (при их наличии)
#Заголовки	Только строка заголовка
#Данные	Только строки данных
#Итого	Только строка итогов
@Имя столбца ИЛИ @ ИЛИ #Эта строка	Ячейка на пересечении текущей строки и указанного столбца (неявное пересечение) Указатель #Эта строка автоматически меняется на указатель @

Ниже приведены примеры структурированных ссылок.

Вся таблица

Только данные

Только заголовки

Только итоги

Таблица Таблица1

Таблица1[#Все]

Таблица1

Таблица1[#Данные]

Таблица1[#Заголовки]

Таблица1[#Итого]

Столбец N

Таблица1[[#Все],[N]]

Таблица1[N]

Таблица1[[#Данные],[N]]

Таблица1[[#Заголовки],[N]]

Таблица1[[#Итого],[N]]

Столбцы с N по M

Таблица1[[#Все],[N]:[M]]

Таблица1[[N]:[M]]

Таблица1[[#Данные],[N]:[M]]

Таблица1[[#Заголовки],[N]:[M]]

Таблица1[[#Итого],[N]:[M]]

Ввод структурированной ссылки в формулу

Ввод формул, которые содержат структурированные ссылки, осуществляется стандартными способами.

Чтобы указать в формуле название «умной» таблицы, выполните следующие действия:

1.Начните вводить название таблицы. В выпадающем списке отобразятся названия всех «умных» таблиц, которые содержатся в документе.

2.Выберите название требуемой таблицы с помощью мыши или клавиш клавиатуры:

•Щелкните по названию таблицы левой кнопкой мыши.

•Выделите название таблицы с помощью клавиш клавиатуры ↓ и ↑ и нажмите клавишу enter Enter.

Название таблицы подставится в формулу.

Чтобы ввести в формулу имя столбца или указатель на область данных таблицы (например, #Итого или @), выполните следующие действия:

1.Введите символ [ (левая квадратная скобка). В выпадающем списке отобразятся названия столбцов и указатели на области данных таблицы.

2.Выберите требуемый элемент списка с помощью мыши или клавиш клавиатуры:

•Щелкните по строке элемента левой кнопкой мыши.

•Выделите строку элемента с помощью клавиш клавиатуры ↓ и ↑ и нажмите клавишу enter Enter.

Выбранный элемент подставится в формулу.

Если указатель на область данных таблицы (например, [#Заголовки]) введен в формулу корректно, то он выделяется цветом, а в таблице подсвечивается диапазон, к которому он обращается (например, строка заголовка).

Был ли материал полезным?

Да

Нет